High Beam Trigger Wire

Hello All,

I am going to be installing a Garmin Power switch soon, and want to use a high beam as a "control" (trigger) wire. I have a 2024 Platinum.

I have seen this thread:

https://www.tundras.com/threads/how...-bus-driven-hi-low-parking-headlights.110264/

Is this the only way to get a signal wire with these trucks? I don't need enough power to run the lights, I just need something as a trigger.

TIA

 

There's no high beam trigger, it is all a data signal on the premium headlights (found opt. on Limited, std. on platinum and above); so yes you'd need a CANM8

 

That's a shame, but oh well.

I noticed our trucks aren't on the compatibility list, but we have determined that they are compatible?

 

The thread you reference has multiple posts showing the device works.

 

I have a canbus reader for sale
https://www.tundras.com/threads/can-m8-canbus-reader.160659/

 

If you're handy you can build one using an ESP32, that is what I did... < $20 all in

 

Have a BOM, and link to instructions and code?

 

Not quite, I'd have to do a writeup - my build was more complicated because I used an ESP32 to do several things.

I built a custom light bar controller using two ESP32s… one reads CAN signals and the other controls the actual lighting hardware. The CAN reader ESP32 listens for high beam activation via the vehicle’s CAN bus and transmits that status wirelessly via ESP-NOW every 100ms.

The controller ESP32 receives the high beam signal and controls a relay that toggles the light bar. It also reads analog voltages using an ADS1115 to determine backlight brightness from factory signals, with smoothing, hysteresis, and transition detection for reliable readings. There’s a physical button for manual control (the OEM lightbar button), and a long press toggles an override mode with a pulsing backlight – when in override mode the lightbar completely ignores the high beam status.

The result is a seamless OEM-like integration with wireless communication between modules. No cutting or tapping into the CAN lines near the front of the vehicle but instead used 30AWG enameled copper wire to tap into the harness itself.


Below is the code for the ESP32 CAN reader which can be modified to be standalone (send a signal out via a pinout) - note this is specifically written to read the high beam status, I didn't spend any time sniffing for other packets.

Code:

#include <esp_now.h>
#include <WiFi.h>
#include "driver/twai.h"

// === PIN & RECEIVER CONFIG ===
#define RX_PIN GPIO_NUM_4
#define TX_PIN GPIO_NUM_16

uint8_t receiverMAC[] = { 0xFD, 0xE3, 0xC0, 0x7C, 0x57, 0xC3 };

// === STATE TRACKING ===
bool currentState = false;
bool lastSentState = false;
unsigned long lastSentTime = 0;

void setup() {
  Serial.begin(115200);
  delay(1000);

  // --- ESP-NOW INIT ---
  WiFi.mode(WIFI_STA);
  if (esp_now_init() != ESP_OK) {
    Serial.println("ESP-NOW init failed");
    while (true);
  }

  esp_now_peer_info_t peerInfo = {};
  memcpy(peerInfo.peer_addr, receiverMAC, 6);
  peerInfo.channel = 0;
  peerInfo.encrypt = false;
  if (esp_now_add_peer(&peerInfo) != ESP_OK) {
    Serial.println("Failed to add ESP-NOW peer");
    while (true);
  }

  Serial.println("ESP-NOW sender ready");

  // --- TWAI CAN INIT ---
  twai_general_config_t g_config = TWAI_GENERAL_CONFIG_DEFAULT(
    RX_PIN, TX_PIN, TWAI_MODE_LISTEN_ONLY
  );
  twai_timing_config_t t_config = TWAI_TIMING_CONFIG_500KBITS();
  twai_filter_config_t f_config = TWAI_FILTER_CONFIG_ACCEPT_ALL();

  if (twai_driver_install(&g_config, &t_config, &f_config) != ESP_OK || twai_start() != ESP_OK) {
    Serial.println("TWAI driver failed");
    while (true);
  }

  Serial.println("CAN sniffer initialized");
}

void loop() {
  twai_message_t msg;
  bool stateChanged = false;

  // Check for CAN message
  if (twai_receive(&msg, pdMS_TO_TICKS(10)) == ESP_OK) {
    if (msg.identifier == 0x699 && msg.data_length_code >= 3) {
      bool newState = msg.data[2] & (1 << 4);  // Byte 2, Bit 4
      if (newState != currentState) {
        currentState = newState;
        stateChanged = true;
      }
    }
  }

  unsigned long now = millis();

  // On state change OR periodic resend every 100ms
  if (stateChanged || (currentState == lastSentState && now - lastSentTime >= 100)) {
    esp_now_send(receiverMAC, (uint8_t *)&currentState, sizeof(currentState));
    Serial.print("Sent high beam state: ");
    Serial.println(currentState ? "ON" : "OFF");
    lastSentTime = now;
    lastSentState = currentState;
  }
}

I can help with the hardware a bit, it all takes a bit of knowhow but it's not too hard.

 

While I greatly appreciate it, I quickly learned after my last RPI project that I should stick to building mechanical things and stay away from trying to build things that work on magic (read: electricity)